Add package WelsonJS.Cryptography

Add package `WelsonJS.Cryptography`

WelsonJS.Toolkit/WelsonJS.Cryptography/SeedAlgorithm.vb

@@ -0,0 +1,56 @@
+' SeedAlgorithm.cs (WelsonJS.Cryptography)
+' SPDX-License-Identifier: MIT
+' SPDX-FileCopyrightText: 2025 Namhyeon Go <gnh1201@catswords.re.kr>, Catswords OSS And WelsonJS Contributors
+' https://github.com/gnh1201/welsonjs
+' 
+Imports System.Security.Cryptography
+
+Public Class SeedAlgorithm
+    Inherits SymmetricAlgorithm
+
+    Public Sub New()
+        LegalBlockSizesValue = New KeySizes() {New KeySizes(128, 128, 0)}
+        LegalKeySizesValue = New KeySizes() {New KeySizes(128, 128, 0)}
+
+        Me.BlockSize = 128
+        Me.KeySize = 128
+        Me.FeedbackSize = 128
+
+        Me.Mode = CipherMode.ECB
+        Me.Padding = PaddingMode.PKCS7
+
+        Me.Key = New Byte(15) {}
+        Me.IV = New Byte(15) {}
+    End Sub
+
+    Public Overrides Sub GenerateKey()
+        Using rng As New RNGCryptoServiceProvider()
+            rng.GetBytes(Me.Key)
+        End Using
+    End Sub
+
+    Public Overrides Sub GenerateIV()
+        Using rng As New RNGCryptoServiceProvider()
+            rng.GetBytes(Me.IV)
+        End Using
+    End Sub
+
+    Public Overrides Function CreateEncryptor(rgbKey As Byte(), rgbIV As Byte()) As ICryptoTransform
+        Return CreateTransform(rgbKey, rgbIV, True)
+    End Function
+
+    Public Overrides Function CreateDecryptor(rgbKey As Byte(), rgbIV As Byte()) As ICryptoTransform
+        Return CreateTransform(rgbKey, rgbIV, False)
+    End Function
+
+    Private Function CreateTransform(key As Byte(), iv As Byte(), encrypt As Boolean) As ICryptoTransform
+        Select Case Me.Mode
+            Case CipherMode.ECB
+                Return New SeedEcbTransform(key, encrypt, Me.Padding)
+            Case Else
+                Throw New NotSupportedException("This mode not supported yet")
+        End Select
+    End Function
+
+    ' TODO: CCM, GCM, CMAC
+End Class

WelsonJS.Toolkit/WelsonJS.Cryptography/SeedCore.vb

@@ -0,0 +1,250 @@
+' SeedCore.cs (WelsonJS.Cryptography)
+' SPDX-License-Identifier: MIT
+' SPDX-FileCopyrightText: 2025 Namhyeon Go <gnh1201@catswords.re.kr>, Catswords OSS And WelsonJS Contributors
+' https://github.com/gnh1201/welsonjs
+' 
+Public Class SeedCore
+    Private ReadOnly roundKey(31) As UInteger
+
+    Private Shared ReadOnly SS0() As UInteger = {
+        &H2989A1A8UI, &H5858184UI, &H16C6D2D4UI, &H13C3D3D0UI, &H14445054UI, &H1D0D111CUI, &H2C8CA0ACUI, &H25052124UI,
+        &H1D4D515CUI, &H3434340UI, &H18081018UI, &H1E0E121CUI, &H11415150UI, &H3CCCF0FCUI, &HACAC2C8UI, &H23436360UI,
+        &H28082028UI, &H4444044UI, &H20002020UI, &H1D8D919CUI, &H20C0E0E0UI, &H22C2E2E0UI, &H8C8C0C8UI, &H17071314UI,
+        &H2585A1A4UI, &HF8F838CUI, &H3030300UI, &H3B4B7378UI, &H3B8BB3B8UI, &H13031310UI, &H12C2D2D0UI, &H2ECEE2ECUI,
+        &H30407070UI, &HC8C808CUI, &H3F0F333CUI, &H2888A0A8UI, &H32023230UI, &H1DCDD1DCUI, &H36C6F2F4UI, &H34447074UI,
+        &H2CCCE0ECUI, &H15859194UI, &HB0B0308UI, &H17475354UI, &H1C4C505CUI, &H1B4B5358UI, &H3D8DB1BCUI, &H1010100UI,
+        &H24042024UI, &H1C0C101CUI, &H33437370UI, &H18889098UI, &H10001010UI, &HCCCC0CCUI, &H32C2F2F0UI, &H19C9D1D8UI,
+        &H2C0C202CUI, &H27C7E3E4UI, &H32427270UI, &H3838380UI, &H1B8B9398UI, &H11C1D1D0UI, &H6868284UI, &H9C9C1C8UI,
+        &H20406060UI, &H10405050UI, &H2383A3A0UI, &H2BCBE3E8UI, &HD0D010CUI, &H3686B2B4UI, &H1E8E929CUI, &HF4F434CUI,
+        &H3787B3B4UI, &H1A4A5258UI, &H6C6C2C4UI, &H38487078UI, &H2686A2A4UI, &H12021210UI, &H2F8FA3ACUI, &H15C5D1D4UI,
+        &H21416160UI, &H3C3C3C0UI, &H3484B0B4UI, &H1414140UI, &H12425250UI, &H3D4D717CUI, &HD8D818CUI, &H8080008UI,
+        &H1F0F131CUI, &H19899198UI, &H0UI, &H19091118UI, &H4040004UI, &H13435350UI, &H37C7F3F4UI, &H21C1E1E0UI,
+        &H3DCDF1FCUI, &H36467274UI, &H2F0F232CUI, &H27072324UI, &H3080B0B0UI, &HB8B8388UI, &HE0E020CUI, &H2B8BA3A8UI,
+        &H2282A2A0UI, &H2E4E626CUI, &H13839390UI, &HD4D414CUI, &H29496168UI, &H3C4C707CUI, &H9090108UI, &HA0A0208UI,
+        &H3F8FB3BCUI, &H2FCFE3ECUI, &H33C3F3F0UI, &H5C5C1C4UI, &H7878384UI, &H14041014UI, &H3ECEF2FCUI, &H24446064UI,
+        &H1ECED2DCUI, &H2E0E222CUI, &HB4B4348UI, &H1A0A1218UI, &H6060204UI, &H21012120UI, &H2B4B6368UI, &H26466264UI,
+        &H2020200UI, &H35C5F1F4UI, &H12829290UI, &HA8A8288UI, &HC0C000CUI, &H3383B3B0UI, &H3E4E727CUI, &H10C0D0D0UI,
+        &H3A4A7278UI, &H7474344UI, &H16869294UI, &H25C5E1E4UI, &H26062224UI, &H808080UI, &H2D8DA1ACUI, &H1FCFD3DCUI,
+        &H2181A1A0UI, &H30003030UI, &H37073334UI, &H2E8EA2ACUI, &H36063234UI, &H15051114UI, &H22022220UI, &H38083038UI,
+        &H34C4F0F4UI, &H2787A3A4UI, &H5454144UI, &HC4C404CUI, &H1818180UI, &H29C9E1E8UI, &H4848084UI, &H17879394UI,
+        &H35053134UI, &HBCBC3C8UI, &HECEC2CCUI, &H3C0C303CUI, &H31417170UI, &H11011110UI, &H7C7C3C4UI, &H9898188UI,
+        &H35457174UI, &H3BCBF3F8UI, &H1ACAD2D8UI, &H38C8F0F8UI, &H14849094UI, &H19495158UI, &H2828280UI, &H4C4C0C4UI,
+        &H3FCFF3FCUI, &H9494148UI, &H39093138UI, &H27476364UI, &HC0C0C0UI, &HFCFC3CCUI, &H17C7D3D4UI, &H3888B0B8UI,
+        &HF0F030CUI, &HE8E828CUI, &H2424240UI, &H23032320UI, &H11819190UI, &H2C4C606CUI, &H1BCBD3D8UI, &H2484A0A4UI,
+        &H34043034UI, &H31C1F1F0UI, &H8484048UI, &H2C2C2C0UI, &H2F4F636CUI, &H3D0D313CUI, &H2D0D212CUI, &H404040UI,
+        &H3E8EB2BCUI, &H3E0E323CUI, &H3C8CB0BCUI, &H1C1C1C0UI, &H2A8AA2A8UI, &H3A8AB2B8UI, &HE4E424CUI, &H15455154UI,
+        &H3B0B3338UI, &H1CCCD0DCUI, &H28486068UI, &H3F4F737CUI, &H1C8C909CUI, &H18C8D0D8UI, &HA4A4248UI, &H16465254UI,
+        &H37477374UI, &H2080A0A0UI, &H2DCDE1ECUI, &H6464244UI, &H3585B1B4UI, &H2B0B2328UI, &H25456164UI, &H3ACAF2F8UI,
+        &H23C3E3E0UI, &H3989B1B8UI, &H3181B1B0UI, &H1F8F939CUI, &H1E4E525CUI, &H39C9F1F8UI, &H26C6E2E4UI, &H3282B2B0UI,
+        &H31013130UI, &H2ACAE2E8UI, &H2D4D616CUI, &H1F4F535CUI, &H24C4E0E4UI, &H30C0F0F0UI, &HDCDC1CCUI, &H8888088UI,
+        &H16061214UI, &H3A0A3238UI, &H18485058UI, &H14C4D0D4UI, &H22426260UI, &H29092128UI, &H7070304UI, &H33033330UI,
+        &H28C8E0E8UI, &H1B0B1318UI, &H5050104UI, &H39497178UI, &H10809090UI, &H2A4A6268UI, &H2A0A2228UI, &H1A8A9298UI
+    }
+
+    Private Shared ReadOnly SS1() As UInteger = {
+        &H38380830UI, &HE828C8E0UI, &H2C2D0D21UI, &HA42686A2UI, &HCC0FCFC3UI, &HDC1ECED2UI, &HB03383B3UI, &HB83888B0UI,
+        &HAC2F8FA3UI, &H60204060UI, &H54154551UI, &HC407C7C3UI, &H44044440UI, &H6C2F4F63UI, &H682B4B63UI, &H581B4B53UI,
+        &HC003C3C3UI, &H60224262UI, &H30330333UI, &HB43585B1UI, &H28290921UI, &HA02080A0UI, &HE022C2E2UI, &HA42787A3UI,
+        &HD013C3D3UI, &H90118191UI, &H10110111UI, &H4060602UI, &H1C1C0C10UI, &HBC3C8CB0UI, &H34360632UI, &H480B4B43UI,
+        &HEC2FCFE3UI, &H88088880UI, &H6C2C4C60UI, &HA82888A0UI, &H14170713UI, &HC404C4C0UI, &H14160612UI, &HF434C4F0UI,
+        &HC002C2C2UI, &H44054541UI, &HE021C1E1UI, &HD416C6D2UI, &H3C3F0F33UI, &H3C3D0D31UI, &H8C0E8E82UI, &H98188890UI,
+        &H28280820UI, &H4C0E4E42UI, &HF436C6F2UI, &H3C3E0E32UI, &HA42585A1UI, &HF839C9F1UI, &HC0D0D01UI, &HDC1FCFD3UI,
+        &HD818C8D0UI, &H282B0B23UI, &H64264662UI, &H783A4A72UI, &H24270723UI, &H2C2F0F23UI, &HF031C1F1UI, &H70324272UI,
+        &H40024242UI, &HD414C4D0UI, &H40014141UI, &HC000C0C0UI, &H70334373UI, &H64274763UI, &HAC2C8CA0UI, &H880B8B83UI,
+        &HF437C7F3UI, &HAC2D8DA1UI, &H80008080UI, &H1C1F0F13UI, &HC80ACAC2UI, &H2C2C0C20UI, &HA82A8AA2UI, &H34340430UI,
+        &HD012C2D2UI, &H80B0B03UI, &HEC2ECEE2UI, &HE829C9E1UI, &H5C1D4D51UI, &H94148490UI, &H18180810UI, &HF838C8F0UI,
+        &H54174753UI, &HAC2E8EA2UI, &H8080800UI, &HC405C5C1UI, &H10130313UI, &HCC0DCDC1UI, &H84068682UI, &HB83989B1UI,
+        &HFC3FCFF3UI, &H7C3D4D71UI, &HC001C1C1UI, &H30310131UI, &HF435C5F1UI, &H880A8A82UI, &H682A4A62UI, &HB03181B1UI,
+        &HD011C1D1UI, &H20200020UI, &HD417C7D3UI, &H20202UI, &H20220222UI, &H4040400UI, &H68284860UI, &H70314171UI,
+        &H4070703UI, &HD81BCBD3UI, &H9C1D8D91UI, &H98198991UI, &H60214161UI, &HBC3E8EB2UI, &HE426C6E2UI, &H58194951UI,
+        &HDC1DCDD1UI, &H50114151UI, &H90108090UI, &HDC1CCCD0UI, &H981A8A92UI, &HA02383A3UI, &HA82B8BA3UI, &HD010C0D0UI,
+        &H80018181UI, &HC0F0F03UI, &H44074743UI, &H181A0A12UI, &HE023C3E3UI, &HEC2CCCE0UI, &H8C0D8D81UI, &HBC3F8FB3UI,
+        &H94168692UI, &H783B4B73UI, &H5C1C4C50UI, &HA02282A2UI, &HA02181A1UI, &H60234363UI, &H20230323UI, &H4C0D4D41UI,
+        &HC808C8C0UI, &H9C1E8E92UI, &H9C1C8C90UI, &H383A0A32UI, &HC0C0C00UI, &H2C2E0E22UI, &HB83A8AB2UI, &H6C2E4E62UI,
+        &H9C1F8F93UI, &H581A4A52UI, &HF032C2F2UI, &H90128292UI, &HF033C3F3UI, &H48094941UI, &H78384870UI, &HCC0CCCC0UI,
+        &H14150511UI, &HF83BCBF3UI, &H70304070UI, &H74354571UI, &H7C3F4F73UI, &H34350531UI, &H10100010UI, &H30303UI,
+        &H64244460UI, &H6C2D4D61UI, &HC406C6C2UI, &H74344470UI, &HD415C5D1UI, &HB43484B0UI, &HE82ACAE2UI, &H8090901UI,
+        &H74364672UI, &H18190911UI, &HFC3ECEF2UI, &H40004040UI, &H10120212UI, &HE020C0E0UI, &HBC3D8DB1UI, &H4050501UI,
+        &HF83ACAF2UI, &H10101UI, &HF030C0F0UI, &H282A0A22UI, &H5C1E4E52UI, &HA82989A1UI, &H54164652UI, &H40034343UI,
+        &H84058581UI, &H14140410UI, &H88098981UI, &H981B8B93UI, &HB03080B0UI, &HE425C5E1UI, &H48084840UI, &H78394971UI,
+        &H94178793UI, &HFC3CCCF0UI, &H1C1E0E12UI, &H80028282UI, &H20210121UI, &H8C0C8C80UI, &H181B0B13UI, &H5C1F4F53UI,
+        &H74374773UI, &H54144450UI, &HB03282B2UI, &H1C1D0D11UI, &H24250521UI, &H4C0F4F43UI, &H0UI, &H44064642UI,
+        &HEC2DCDE1UI, &H58184850UI, &H50124252UI, &HE82BCBE3UI, &H7C3E4E72UI, &HD81ACAD2UI, &HC809C9C1UI, &HFC3DCDF1UI,
+        &H30300030UI, &H94158591UI, &H64254561UI, &H3C3C0C30UI, &HB43686B2UI, &HE424C4E0UI, &HB83B8BB3UI, &H7C3C4C70UI,
+        &HC0E0E02UI, &H50104050UI, &H38390931UI, &H24260622UI, &H30320232UI, &H84048480UI, &H68294961UI, &H90138393UI,
+        &H34370733UI, &HE427C7E3UI, &H24240420UI, &HA42484A0UI, &HC80BCBC3UI, &H50134353UI, &H80A0A02UI, &H84078783UI,
+        &HD819C9D1UI, &H4C0C4C40UI, &H80038383UI, &H8C0F8F83UI, &HCC0ECEC2UI, &H383B0B33UI, &H480A4A42UI, &HB43787B3UI
+    }
+    Private Shared ReadOnly SS2() As UInteger = {
+        &HA1A82989UI, &H81840585UI, &HD2D416C6UI, &HD3D013C3UI, &H50541444UI, &H111C1D0DUI, &HA0AC2C8CUI, &H21242505UI,
+        &H515C1D4DUI, &H43400343UI, &H10181808UI, &H121C1E0EUI, &H51501141UI, &HF0FC3CCCUI, &HC2C80ACAUI, &H63602343UI,
+        &H20282808UI, &H40440444UI, &H20202000UI, &H919C1D8DUI, &HE0E020C0UI, &HE2E022C2UI, &HC0C808C8UI, &H13141707UI,
+        &HA1A42585UI, &H838C0F8FUI, &H3000303UI, &H73783B4BUI, &HB3B83B8BUI, &H13101303UI, &HD2D012C2UI, &HE2EC2ECEUI,
+        &H70703040UI, &H808C0C8CUI, &H333C3F0FUI, &HA0A82888UI, &H32303202UI, &HD1DC1DCDUI, &HF2F436C6UI, &H70743444UI,
+        &HE0EC2CCCUI, &H91941585UI, &H3080B0BUI, &H53541747UI, &H505C1C4CUI, &H53581B4BUI, &HB1BC3D8DUI, &H1000101UI,
+        &H20242404UI, &H101C1C0CUI, &H73703343UI, &H90981888UI, &H10101000UI, &HC0CC0CCCUI, &HF2F032C2UI, &HD1D819C9UI,
+        &H202C2C0CUI, &HE3E427C7UI, &H72703242UI, &H83800383UI, &H93981B8BUI, &HD1D011C1UI, &H82840686UI, &HC1C809C9UI,
+        &H60602040UI, &H50501040UI, &HA3A02383UI, &HE3E82BCBUI, &H10C0D0DUI, &HB2B43686UI, &H929C1E8EUI, &H434C0F4FUI,
+        &HB3B43787UI, &H52581A4AUI, &HC2C406C6UI, &H70783848UI, &HA2A42686UI, &H12101202UI, &HA3AC2F8FUI, &HD1D415C5UI,
+        &H61602141UI, &HC3C003C3UI, &HB0B43484UI, &H41400141UI, &H52501242UI, &H717C3D4DUI, &H818C0D8DUI, &H80808UI,
+        &H131C1F0FUI, &H91981989UI, &H0UI, &H11181909UI, &H40404UI, &H53501343UI, &HF3F437C7UI, &HE1E021C1UI,
+        &HF1FC3DCDUI, &H72743646UI, &H232C2F0FUI, &H23242707UI, &HB0B03080UI, &H83880B8BUI, &H20C0E0EUI, &HA3A82B8BUI,
+        &HA2A02282UI, &H626C2E4EUI, &H93901383UI, &H414C0D4DUI, &H61682949UI, &H707C3C4CUI, &H1080909UI, &H2080A0AUI,
+        &HB3BC3F8FUI, &HE3EC2FCFUI, &HF3F033C3UI, &HC1C405C5UI, &H83840787UI, &H10141404UI, &HF2FC3ECEUI, &H60642444UI,
+        &HD2DC1ECEUI, &H222C2E0EUI, &H43480B4BUI, &H12181A0AUI, &H2040606UI, &H21202101UI, &H63682B4BUI, &H62642646UI,
+        &H2000202UI, &HF1F435C5UI, &H92901282UI, &H82880A8AUI, &HC0C0CUI, &HB3B03383UI, &H727C3E4EUI, &HD0D010C0UI,
+        &H72783A4AUI, &H43440747UI, &H92941686UI, &HE1E425C5UI, &H22242606UI, &H80800080UI, &HA1AC2D8DUI, &HD3DC1FCFUI,
+        &HA1A02181UI, &H30303000UI, &H33343707UI, &HA2AC2E8EUI, &H32343606UI, &H11141505UI, &H22202202UI, &H30383808UI,
+        &HF0F434C4UI, &HA3A42787UI, &H41440545UI, &H404C0C4CUI, &H81800181UI, &HE1E829C9UI, &H80840484UI, &H93941787UI,
+        &H31343505UI, &HC3C80BCBUI, &HC2CC0ECEUI, &H303C3C0CUI, &H71703141UI, &H11101101UI, &HC3C407C7UI, &H81880989UI,
+        &H71743545UI, &HF3F83BCBUI, &HD2D81ACAUI, &HF0F838C8UI, &H90941484UI, &H51581949UI, &H82800282UI, &HC0C404C4UI,
+        &HF3FC3FCFUI, &H41480949UI, &H31383909UI, &H63642747UI, &HC0C000C0UI, &HC3CC0FCFUI, &HD3D417C7UI, &HB0B83888UI,
+        &H30C0F0FUI, &H828C0E8EUI, &H42400242UI, &H23202303UI, &H91901181UI, &H606C2C4CUI, &HD3D81BCBUI, &HA0A42484UI,
+        &H30343404UI, &HF1F031C1UI, &H40480848UI, &HC2C002C2UI, &H636C2F4FUI, &H313C3D0DUI, &H212C2D0DUI, &H40400040UI,
+        &HB2BC3E8EUI, &H323C3E0EUI, &HB0BC3C8CUI, &HC1C001C1UI, &HA2A82A8AUI, &HB2B83A8AUI, &H424C0E4EUI, &H51541545UI,
+        &H33383B0BUI, &HD0DC1CCCUI, &H60682848UI, &H737C3F4FUI, &H909C1C8CUI, &HD0D818C8UI, &H42480A4AUI, &H52541646UI,
+        &H73743747UI, &HA0A02080UI, &HE1EC2DCDUI, &H42440646UI, &HB1B43585UI, &H23282B0BUI, &H61642545UI, &HF2F83ACAUI,
+        &HE3E023C3UI, &HB1B83989UI, &HB1B03181UI, &H939C1F8FUI, &H525C1E4EUI, &HF1F839C9UI, &HE2E426C6UI, &HB2B03282UI,
+        &H31303101UI, &HE2E82ACAUI, &H616C2D4DUI, &H535C1F4FUI, &HE0E424C4UI, &HF0F030C0UI, &HC1CC0DCDUI, &H80880888UI,
+        &H12141606UI, &H32383A0AUI, &H50581848UI, &HD0D414C4UI, &H62602242UI, &H21282909UI, &H3040707UI, &H33303303UI,
+        &HE0E828C8UI, &H13181B0BUI, &H1040505UI, &H71783949UI, &H90901080UI, &H62682A4AUI, &H22282A0AUI, &H92981A8AUI
+    }
+    Private Shared ReadOnly SS3() As UInteger = {
+        &H8303838UI, &HC8E0E828UI, &HD212C2DUI, &H86A2A426UI, &HCFC3CC0FUI, &HCED2DC1EUI, &H83B3B033UI, &H88B0B838UI,
+        &H8FA3AC2FUI, &H40606020UI, &H45515415UI, &HC7C3C407UI, &H44404404UI, &H4F636C2FUI, &H4B63682BUI, &H4B53581BUI,
+        &HC3C3C003UI, &H42626022UI, &H3333033UI, &H85B1B435UI, &H9212829UI, &H80A0A020UI, &HC2E2E022UI, &H87A3A427UI,
+        &HC3D3D013UI, &H81919011UI, &H1111011UI, &H6020406UI, &HC101C1CUI, &H8CB0BC3CUI, &H6323436UI, &H4B43480BUI,
+        &HCFE3EC2FUI, &H88808808UI, &H4C606C2CUI, &H88A0A828UI, &H7131417UI, &HC4C0C404UI, &H6121416UI, &HC4F0F434UI,
+        &HC2C2C002UI, &H45414405UI, &HC1E1E021UI, &HC6D2D416UI, &HF333C3FUI, &HD313C3DUI, &H8E828C0EUI, &H88909818UI,
+        &H8202828UI, &H4E424C0EUI, &HC6F2F436UI, &HE323C3EUI, &H85A1A425UI, &HC9F1F839UI, &HD010C0DUI, &HCFD3DC1FUI,
+        &HC8D0D818UI, &HB23282BUI, &H46626426UI, &H4A72783AUI, &H7232427UI, &HF232C2FUI, &HC1F1F031UI, &H42727032UI,
+        &H42424002UI, &HC4D0D414UI, &H41414001UI, &HC0C0C000UI, &H43737033UI, &H47636427UI, &H8CA0AC2CUI, &H8B83880BUI,
+        &HC7F3F437UI, &H8DA1AC2DUI, &H80808000UI, &HF131C1FUI, &HCAC2C80AUI, &HC202C2CUI, &H8AA2A82AUI, &H4303434UI,
+        &HC2D2D012UI, &HB03080BUI, &HCEE2EC2EUI, &HC9E1E829UI, &H4D515C1DUI, &H84909414UI, &H8101818UI, &HC8F0F838UI,
+        &H47535417UI, &H8EA2AC2EUI, &H8000808UI, &HC5C1C405UI, &H3131013UI, &HCDC1CC0DUI, &H86828406UI, &H89B1B839UI,
+        &HCFF3FC3FUI, &H4D717C3DUI, &HC1C1C001UI, &H1313031UI, &HC5F1F435UI, &H8A82880AUI, &H4A62682AUI, &H81B1B031UI,
+        &HC1D1D011UI, &H202020UI, &HC7D3D417UI, &H2020002UI, &H2222022UI, &H4000404UI, &H48606828UI, &H41717031UI,
+        &H7030407UI, &HCBD3D81BUI, &H8D919C1DUI, &H89919819UI, &H41616021UI, &H8EB2BC3EUI, &HC6E2E426UI, &H49515819UI,
+        &HCDD1DC1DUI, &H41515011UI, &H80909010UI, &HCCD0DC1CUI, &H8A92981AUI, &H83A3A023UI, &H8BA3A82BUI, &HC0D0D010UI,
+        &H81818001UI, &HF030C0FUI, &H47434407UI, &HA12181AUI, &HC3E3E023UI, &HCCE0EC2CUI, &H8D818C0DUI, &H8FB3BC3FUI,
+        &H86929416UI, &H4B73783BUI, &H4C505C1CUI, &H82A2A022UI, &H81A1A021UI, &H43636023UI, &H3232023UI, &H4D414C0DUI,
+        &HC8C0C808UI, &H8E929C1EUI, &H8C909C1CUI, &HA32383AUI, &HC000C0CUI, &HE222C2EUI, &H8AB2B83AUI, &H4E626C2EUI,
+        &H8F939C1FUI, &H4A52581AUI, &HC2F2F032UI, &H82929012UI, &HC3F3F033UI, &H49414809UI, &H48707838UI, &HCCC0CC0CUI,
+        &H5111415UI, &HCBF3F83BUI, &H40707030UI, &H45717435UI, &H4F737C3FUI, &H5313435UI, &H101010UI, &H3030003UI,
+        &H44606424UI, &H4D616C2DUI, &HC6C2C406UI, &H44707434UI, &HC5D1D415UI, &H84B0B434UI, &HCAE2E82AUI, &H9010809UI,
+        &H46727436UI, &H9111819UI, &HCEF2FC3EUI, &H40404000UI, &H2121012UI, &HC0E0E020UI, &H8DB1BC3DUI, &H5010405UI,
+        &HCAF2F83AUI, &H1010001UI, &HC0F0F030UI, &HA22282AUI, &H4E525C1EUI, &H89A1A829UI, &H46525416UI, &H43434003UI,
+        &H85818405UI, &H4101414UI, &H89818809UI, &H8B93981BUI, &H80B0B030UI, &HC5E1E425UI, &H48404808UI, &H49717839UI,
+        &H87939417UI, &HCCF0FC3CUI, &HE121C1EUI, &H82828002UI, &H1212021UI, &H8C808C0CUI, &HB13181BUI, &H4F535C1FUI,
+        &H47737437UI, &H44505414UI, &H82B2B032UI, &HD111C1DUI, &H5212425UI, &H4F434C0FUI, &H0UI, &H46424406UI,
+        &HCDE1EC2DUI, &H48505818UI, &H42525012UI, &HCBE3E82BUI, &H4E727C3EUI, &HCAD2D81AUI, &HC9C1C809UI, &HCDF1FC3DUI,
+        &H303030UI, &H85919415UI, &H45616425UI, &HC303C3CUI, &H86B2B436UI, &HC4E0E424UI, &H8BB3B83BUI, &H4C707C3CUI,
+        &HE020C0EUI, &H40505010UI, &H9313839UI, &H6222426UI, &H2323032UI, &H84808404UI, &H49616829UI, &H83939013UI,
+        &H7333437UI, &HC7E3E427UI, &H4202424UI, &H84A0A424UI, &HCBC3C80BUI, &H43535013UI, &HA02080AUI, &H87838407UI,
+        &HC9D1D819UI, &H4C404C0CUI, &H83838003UI, &H8F838C0FUI, &HCEC2CC0EUI, &HB33383BUI, &H4A42480AUI, &H87B3B437UI
+    }
+
+    Private Shared ReadOnly KC() As UInteger = {
+        &H9E3779B9UI, &H3C6EF373UI, &H78DDE6E6UI, &HF1BBCDCCUI,
+        &HE3779B99UI, &HC6EF3733UI, &H8DDE6E67UI, &H1BBCDCCFUI,
+        &H3779B99EUI, &H6EF3733CUI, &HDDE6E678UI, &HBBCDCCF1UI,
+        &H779B99E3UI, &HEF3733C6UI, &HDE6E678DUI, &HBCDCCF1BUI
+    }
+
+    Public Sub New(key As Byte())
+        If key.Length <> 16 Then Throw New ArgumentException("SEED key must be 16 bytes.")
+        KeySchedule(key)
+    End Sub
+
+    ' Extract a byte (0 = LSB, 3 = MSB)
+    Private Shared Function GetByte(n As UInteger, index As Integer) As Byte
+        Return CByte((n >> (index * 8)) And &HFF)
+    End Function
+
+    Private Shared Function RoundFunction(T0 As UInteger, T1 As UInteger) As Tuple(Of UInteger, UInteger)
+        T1 = T1 Xor T0
+        T1 = SS0(GetByte(T1, 0)) Xor SS1(GetByte(T1, 1)) Xor SS2(GetByte(T1, 2)) Xor SS3(GetByte(T1, 3))
+        T0 = (T0 + T1) And &HFFFFFFFFUI
+        T0 = SS0(GetByte(T0, 0)) Xor SS1(GetByte(T0, 1)) Xor SS2(GetByte(T0, 2)) Xor SS3(GetByte(T0, 3))
+        T1 = (T1 + T0) And &HFFFFFFFFUI
+        T1 = SS0(GetByte(T1, 0)) Xor SS1(GetByte(T1, 1)) Xor SS2(GetByte(T1, 2)) Xor SS3(GetByte(T1, 3))
+        T0 = (T0 + T1) And &HFFFFFFFFUI
+        Return Tuple.Create(T0, T1)
+    End Function
+
+    Private Sub KeySchedule(userKey As Byte())
+        Dim A As UInteger = BitConverter.ToUInt32(userKey, 0)
+        Dim B As UInteger = BitConverter.ToUInt32(userKey, 4)
+        Dim C As UInteger = BitConverter.ToUInt32(userKey, 8)
+        Dim D As UInteger = BitConverter.ToUInt32(userKey, 12)
+
+        For i As Integer = 0 To 15
+            Dim T0 As UInteger = (A + C - KC(i)) And &HFFFFFFFFUI
+            Dim T1 As UInteger = (B - D + KC(i)) And &HFFFFFFFFUI
+            roundKey(2 * i) = SS0(GetByte(T0, 0)) Xor SS1(GetByte(T0, 1)) Xor SS2(GetByte(T0, 2)) Xor SS3(GetByte(T0, 3))
+            roundKey(2 * i + 1) = SS0(GetByte(T1, 0)) Xor SS1(GetByte(T1, 1)) Xor SS2(GetByte(T1, 2)) Xor SS3(GetByte(T1, 3))
+
+            If i Mod 2 = 0 Then
+                Dim tmpA = A
+                A = (A >> 8) Or (B << 24)
+                B = (B >> 8) Or (tmpA << 24)
+            Else
+                Dim tmpC = C
+                C = (C << 8) Or (D >> 24)
+                D = (D << 8) Or (tmpC >> 24)
+            End If
+        Next
+    End Sub
+
+    Public Sub EncryptBlock(input() As Byte, inOffset As Integer, output() As Byte, outOffset As Integer)
+        Dim L0 = BitConverter.ToUInt32(input, inOffset)
+        Dim L1 = BitConverter.ToUInt32(input, inOffset + 4)
+        Dim R0 = BitConverter.ToUInt32(input, inOffset + 8)
+        Dim R1 = BitConverter.ToUInt32(input, inOffset + 12)
+
+        For i As Integer = 0 To 15
+            Dim t = RoundFunction(R0 Xor roundKey(2 * i), R1 Xor roundKey(2 * i + 1))
+            Dim T0 = t.Item1
+            Dim T1 = t.Item2
+
+            L0 = L0 Xor T0
+            L1 = L1 Xor T1
+
+            ' swap
+            Dim tmp0 = L0 : Dim tmp1 = L1
+            L0 = R0 : L1 = R1
+            R0 = tmp0 : R1 = tmp1
+        Next
+
+        Array.Copy(BitConverter.GetBytes(R0), 0, output, outOffset, 4)
+        Array.Copy(BitConverter.GetBytes(R1), 0, output, outOffset + 4, 4)
+        Array.Copy(BitConverter.GetBytes(L0), 0, output, outOffset + 8, 4)
+        Array.Copy(BitConverter.GetBytes(L1), 0, output, outOffset + 12, 4)
+    End Sub
+
+    Public Sub DecryptBlock(input() As Byte, inOffset As Integer, output() As Byte, outOffset As Integer)
+        Dim L0 = BitConverter.ToUInt32(input, inOffset)
+        Dim L1 = BitConverter.ToUInt32(input, inOffset + 4)
+        Dim R0 = BitConverter.ToUInt32(input, inOffset + 8)
+        Dim R1 = BitConverter.ToUInt32(input, inOffset + 12)
+
+        For i As Integer = 0 To 15
+            Dim t = RoundFunction(R0 Xor roundKey(30 - 2 * i), R1 Xor roundKey(31 - 2 * i))
+            Dim T0 = t.Item1
+            Dim T1 = t.Item2
+
+            L0 = L0 Xor T0
+            L1 = L1 Xor T1
+
+            ' swap
+            Dim tmp0 = L0 : Dim tmp1 = L1
+            L0 = R0 : L1 = R1
+            R0 = tmp0 : R1 = tmp1
+        Next
+
+        Array.Copy(BitConverter.GetBytes(R0), 0, output, outOffset, 4)
+        Array.Copy(BitConverter.GetBytes(R1), 0, output, outOffset + 4, 4)
+        Array.Copy(BitConverter.GetBytes(L0), 0, output, outOffset + 8, 4)
+        Array.Copy(BitConverter.GetBytes(L1), 0, output, outOffset + 12, 4)
+    End Sub
+End Class

WelsonJS.Toolkit/WelsonJS.Cryptography/SeedEcbTransform.vb

@@ -0,0 +1,151 @@
+' SeedEcbTransform.cs (WelsonJS.Cryptography)
+' SPDX-License-Identifier: MIT
+' SPDX-FileCopyrightText: 2025 Namhyeon Go <gnh1201@catswords.re.kr>, Catswords OSS And WelsonJS Contributors
+' https://github.com/gnh1201/welsonjs
+' 
+Imports System.Security.Cryptography
+
+Public Class SeedEcbTransform
+    Implements ICryptoTransform
+
+    Private ReadOnly seedCore As SeedCore
+    Private ReadOnly encrypt As Boolean
+    Private ReadOnly paddingMode As PaddingMode
+
+    Public Sub New(key As Byte(), encryptMode As Boolean, Optional mode As PaddingMode = PaddingMode.PKCS7)
+        seedCore = New SeedCore(key)
+        encrypt = encryptMode
+        paddingMode = mode
+    End Sub
+
+    Public ReadOnly Property InputBlockSize As Integer Implements ICryptoTransform.InputBlockSize
+        Get
+            Return 16
+        End Get
+    End Property
+
+    Public ReadOnly Property OutputBlockSize As Integer Implements ICryptoTransform.OutputBlockSize
+        Get
+            Return 16
+        End Get
+    End Property
+
+    Public ReadOnly Property CanTransformMultipleBlocks As Boolean Implements ICryptoTransform.CanTransformMultipleBlocks
+        Get
+            Return True
+        End Get
+    End Property
+
+    Public ReadOnly Property CanReuseTransform As Boolean Implements ICryptoTransform.CanReuseTransform
+        Get
+            Return True
+        End Get
+    End Property
+
+    Public Function TransformBlock(input() As Byte, inputOffset As Integer, inputCount As Integer,
+                                   output() As Byte, outputOffset As Integer) As Integer Implements ICryptoTransform.TransformBlock
+        If inputCount <= 0 Then
+            Return 0
+        End If
+
+        Dim blockSize = InputBlockSize
+
+        For i As Integer = 0 To inputCount - 1 Step blockSize
+            If encrypt Then
+                seedCore.EncryptBlock(input, inputOffset + i, output, outputOffset + i)
+            Else
+                seedCore.DecryptBlock(input, inputOffset + i, output, outputOffset + i)
+            End If
+        Next
+
+        Return inputCount
+    End Function
+
+    Public Function TransformFinalBlock(input() As Byte, inputOffset As Integer, inputCount As Integer) As Byte() Implements ICryptoTransform.TransformFinalBlock
+        If inputCount = 0 Then
+            Return Array.Empty(Of Byte)()
+        End If
+
+        Dim blockSize As Integer = InputBlockSize
+        Dim paddedLength As Integer
+        Dim buffer() As Byte
+
+        If encrypt Then
+            Select Case paddingMode
+                Case PaddingMode.None
+                    If (inputCount Mod blockSize) <> 0 Then
+                        Throw New CryptographicException("Input data is not a multiple of block size and PaddingMode is None.")
+                    End If
+                    paddedLength = inputCount
+
+                Case PaddingMode.Zeros
+                    paddedLength = ((inputCount + blockSize - 1) \ blockSize) * blockSize
+
+                Case PaddingMode.PKCS7
+                    paddedLength = ((inputCount + blockSize - 1) \ blockSize) * blockSize
+
+                Case Else
+                    Throw New NotSupportedException("Unsupported padding mode: " & paddingMode.ToString())
+            End Select
+
+            buffer = New Byte(paddedLength - 1) {}
+            Array.Copy(input, inputOffset, buffer, 0, inputCount)
+
+            If paddingMode = PaddingMode.Zeros Then
+                ' All filling to zero
+            ElseIf paddingMode = PaddingMode.PKCS7 Then
+                Dim padValue As Byte = CByte(paddedLength - inputCount)
+                For i As Integer = inputCount To paddedLength - 1
+                    buffer(i) = padValue
+                Next
+            End If
+
+            TransformBlock(buffer, 0, paddedLength, buffer, 0)
+            Return buffer
+
+        Else
+            ' Decrpytion
+            If (inputCount Mod blockSize) <> 0 Then
+                Throw New CryptographicException("Encrypted data is not a multiple of block size.")
+            End If
+
+            buffer = New Byte(inputCount - 1) {}
+            TransformBlock(input, inputOffset, inputCount, buffer, 0)
+
+            Select Case paddingMode
+                Case PaddingMode.None
+                    Return buffer
+
+                Case PaddingMode.Zeros
+                    Dim trimLength As Integer = buffer.Length
+                    While trimLength > 0 AndAlso buffer(trimLength - 1) = 0
+                        trimLength -= 1
+                    End While
+                    Dim result(trimLength - 1) As Byte
+                    Array.Copy(buffer, 0, result, 0, trimLength)
+                    Return result
+
+                Case PaddingMode.PKCS7
+                    Dim padValue As Integer = buffer(buffer.Length - 1)
+                    If padValue <= 0 OrElse padValue > blockSize Then
+                        Throw New CryptographicException("Invalid PKCS7 padding.")
+                    End If
+                    For i As Integer = buffer.Length - padValue To buffer.Length - 1
+                        If buffer(i) <> padValue Then
+                            Throw New CryptographicException("Invalid PKCS7 padding.")
+                        End If
+                    Next
+                    Dim result(buffer.Length - padValue - 1) As Byte
+                    Array.Copy(buffer, 0, result, 0, result.Length)
+                    Return result
+
+                Case Else
+                    Throw New NotSupportedException("Unsupported padding mode: " & paddingMode.ToString())
+            End Select
+        End If
+    End Function
+
+    Public Sub Dispose() Implements IDisposable.Dispose
+        ' Nothing
+    End Sub
+End Class

WelsonJS.Toolkit/WelsonJS.Cryptography/WelsonJS.Cryptography.vbproj

@@ -0,0 +1,34 @@
+<Project Sdk="Microsoft.NET.Sdk">
+
+  <PropertyGroup>
+    <RootNamespace>WelsonJS.Cryptography</RootNamespace>
+    <TargetFramework>netstandard2.0</TargetFramework>
+    <RepositoryUrl>https://github.com/gnh1201/welsonjs</RepositoryUrl>
+    <RepositoryType>git</RepositoryType>
+    <PackageProjectUrl>https://github.com/gnh1201/welsonjs</PackageProjectUrl>
+    <Copyright>Catswords OSS</Copyright>
+    <Company>Catswords Research</Company>
+    <Authors>Namhyeon Go,Catswords OSS</Authors>
+    <Platforms>AnyCPU;x86</Platforms>
+    <PackageLicenseExpression>MIT</PackageLicenseExpression>
+    <AssemblyVersion>0.2.7.55</AssemblyVersion>
+    <FileVersion>0.2.7.55</FileVersion>
+  </PropertyGroup>
+
+  <PropertyGroup Condition="'$(Configuration)|$(Platform)'=='Debug|AnyCPU'">
+    <RemoveIntegerChecks>True</RemoveIntegerChecks>
+  </PropertyGroup>
+
+  <PropertyGroup Condition="'$(Configuration)|$(Platform)'=='Debug|x86'">
+    <RemoveIntegerChecks>True</RemoveIntegerChecks>
+  </PropertyGroup>
+
+  <PropertyGroup Condition="'$(Configuration)|$(Platform)'=='Release|AnyCPU'">
+    <RemoveIntegerChecks>True</RemoveIntegerChecks>
+  </PropertyGroup>
+
+  <PropertyGroup Condition="'$(Configuration)|$(Platform)'=='Release|x86'">
+    <RemoveIntegerChecks>True</RemoveIntegerChecks>
+  </PropertyGroup>
+
+</Project>